/* get today's movies and playing times, sort and display them in Excel */
arr = parseKino()    -- parse movies, returns parsed data in 2-dimensional array
call add2excel arr   -- add to Excel


::routine parseKino  -- get and parse website, return array with parsed data
   command="curl https://www.votivkino.at/programm/tag/"
   outArr=.array~new             -- array for stdout
   ADDRESS SYSTEM command WITH OUTPUT USING (outArr)
      -- "parse" works on strings only, so it requests the string value from Rexx objects automatically
   parse var outArr data 'no-further-films'  -- no films afterwards, cut off

   arr=.array~new
   do counter c while data<>""   -- as long as data available
       parse var data '<a href="https://www.votivkino.at/film/' film '/"' .   -
                      '<time datetime="' d 'T' t '"' .                        -
                      '<span class="location' . '>' kino '|' saal '<'         -
                      data
       if film="" then leave     -- no more movies
       arr[c,1]=repl(kino)       -- theater
       arr[c,2]=repl(saal)       -- room
       arr[c,3]=d                -- date
       arr[c,4]=t                -- time
       arr[c,5]=repl(film)       -- movie
       -- for debugging:
       say "#" c":" "09"x arr[c,1] "|" "09"x arr[c,2] "|" "09"x arr[c,3]  "|" "09"x arr[c,4] "|" "09"x arr[c,5]
   end
   return arr        -- return array with the parsed data


::routine repl       -- replace '&nbsp;', '&thinsp;' and '-' with ' '
   return arg(1)~changeStr("&nbsp;"," ")~changeStr("&thinsp;"," ")~changeStr("-"," ")


::routine add2excel  -- create Excel, add data, adjust column sizes, sort data
   use arg arr       -- two dimensional array with movie data

   excelApp = .OLEObject~new("Excel.Application")
   excelApp~visible = .true
   sheet = excelApp~Workbooks~Add~Worksheets[1]

      -- add titles and format them
   titleRange = sheet~range("A1:E1")
   titleRange~font~bold = .true
   titleRange~interior~colorIndex = 36
      -- one can define a single dimensioned array for the cell range
   titleRange~value=.array~of("Kino", "Saal", "Datum", "Zeit", "Film")

      -- add movies
   nrMovies=arr~dimension(1)     -- number of items in first dimension
   movieRange = sheet~range("A2:E" || (nrMovies+1))   -- account for title line
   movieRange~value=arr          -- two dimensional array with all data from array

      -- adjust columns
   sheet~columns~AutoFit

      -- sort (cf. https://docs.microsoft.com/en-us/office/vba/api/excel.range.sort)
   asc = excelApp~getConstant("xlAscending") -- default (could be omitted as argument)
   desc = excelApp~getConstant("xlDescending")

   colTheater=sheet~range("A2")           -- sort by theater
   colDate   =sheet~range("C2")           -- sort by date
   colTime   =sheet~range("D2")           -- sort by time

      -- notes: - theater column will be sorted descendingly
      --        - after second column there is an optional "type" argument to be left out!
      --        - the second sort order is left out as well, defaults to "ascending"
   movieRange~sort(colTheater, desc, colDate, /* type */ , /* order2 */ , colTime, asc)
   return                        -- we are done