-- durchzusuchendes Verzeichnis:
dir    = directory() -- aktuelles Verzeichnis (kann geändert werden)

muster = "*.xlsx"    -- Suchmuster für alle Excel-Dateien


   -- sysFileTree(): vgl. rexxref.pdf, 8.22. SysFileTree
filespec = dir"\"muster
opts     = "FO"      -- nur Dateien suchen, vollqualifzierter Pfad
say "SysFileTree:"
say "filespec:" filespec
say "opts    :" opts "(files only, fully qualifed)"
say

call sysFileTree filespec, "files.", opts

say "found   :" files.0 "Datei(en)"
do i=1 to files.0
   say "09"x "#" i":" files.i -- "09"x ist hexadezimale Zeichenkette für Tabulatorzeichen
end
say "---"
say

   -- vgl. Foliensatz 060_ooRexx
command = "dir /b" quote(filespec)  -- sicherheitshalber Dateinamen in doppelete Anführungszeichen!
say "command :" command
say
arrRes  = .array~new
address system command with output using (arrRes)

say "found   :" arrRes~items "Datei(en)"
do i=1 to arrRes~items
   say "09"x "#" i":" arrRes[i]  -- "09"x ist hexadezimale Zeichenkette für Tabulatorzeichen
   -- alternatively, prepend each unqualified filename with directory():
   -- say "09"x "#" i":" dir"\"arrRes[i]  -- "09"x ist hexadezimale Zeichenkette für Tabulatorzeichen
end


::routine quote      -- Zeichenkette in doppelte Anführungszeichen
  return '"' || arg(1) || '"'